1 REM "THE EMERALD ELEPHANT OF CIPANGU"
2 REM A MINI-ADVENTURE, JUST TO SHOW HOW IT'S DONE.  FOR THE 64--IT WON'T FIT
3 REM ON AN UNEXPANDED VIC.  IF YOU HAVE AN EXPANDED VIC, CHANGE THE TEXT SO IT
4 REM WILL FIT PROPERLY ON THE SCREEN.
5 REM
6 REM RD=ROOM DIRECTION TABLE.  CW$=COMMAND WORD TABLE.  RN$=ROOM NAMES
7 REM KS=KEYSTROKE TABLE.  TN$="THING" NAME TABLE.  TS$="THING" SHORT NAMES
8 REM TL="THING" LOCATION TABLE (ROOM #).  VS=VISIT TABLE: NON-ZERO IF VISITED.
9 REM
10 DIM RD(14,8),CW$(16),RN$(60),KS(64),TN$(9),TS$(9),TL(9),VS(14)
20 GOSUB 1000
25 GOSUB 970
27 REM
28 REM SET UP BLANK LINES AND POSITION STRINGS
29 REM
30 BL$="                   "
31 RL$="":FOR I=1 TO 78:RL$=RL$+" ":NEXT:RL$=RL$+""
32 TL$="":FOR I=1 TO 78:TL$=TL$+" ":NEXT:TL$=TL$+""
33 DL$=""
34 T$="   WITHIN YOUR REACH IS . . . ."
35 C$=CHR$(13)
60 PRINT "[147]CAREFUL!"C$C$"JUST THROUGH THOSE TREES IS THE CASTLE"
61 PRINT "OF DARKNESS."C$C$"ONCE YOU SEE IT, YOU'LL BE STRUCK BLIND"
62 PRINT "UNTIL YOU LEAVE."C$C$"BUT HIDDEN IN A SECRET TREASURE ROOM"
63 PRINT "SOMEWHERE IN THE CASTLE IS THE EMERALD"
64 PRINT "ELEPHANT OF CIPANGU.  THE TOUCH OF THE"
65 PRINT "ELEPHANT WILL GIVE YOU THE PRICELESS"
66 PRINT "GIFT OF FAR SIGHT, WHICH WILL LET YOU"
67 PRINT "SEE TO THE ENDS OF THE EARTH.  WHATEVER"
68 PRINT "PLACE YOU THINK OF, YOU WILL SEE."C$C$"(PRESS ANY KEY)":GOSUB 990
69 PRINT "[147]AS FOR ME, I SEEM TO YOU TO BE MERELY A"
70 PRINT "FIREFLY.  I AM REALLY SOMETHING ELSE"
71 PRINT "ENTIRELY, AND ONCE YOU GET THE ELEPHANT"
72 PRINT "AND LEAVE THE CASTLE, YOU WILL SEE ME ASI REALLY AM."C$
73 PRINT "WILL YOU COME WITH ME?  I'LL BE YOUR"
74 PRINT "EYES, WHILE YOU DECIDE WHERE WE SHOULD  GO."C$
75 PRINT "YOU CAN PRESS A SINGLE KEY TO GO U[154]P,"
76 PRINT "D[154]OWN, I[154]N, O[154]UT, N[154]ORTH, S[154]OUTH, E[154]AST, W[154]EST, OR B[154]ACK."C$
77 PRINT "YOU CAN ALSO T[154]AKE SOMETHING, L[154]EAVE IT"
78 PRINT "BEHIND, TELL ME TO P[154]EER CLOSELY AT"
79 PRINT "THINGS AROUND US, CHECK TO SEE WHAT WE"
80 PRINT "HAVE G[154]OT, Q[154]UIT, OR ASK FOR H[154]ELP (?[154])."C$C$"(PRESS ANY KEY)"
81 GOSUB 990
87 REM
88 REM INITIAL POSITION
89 REM
90 XX=1:XR=1:PR=1:GOSUB 350
97 REM
98 REM MAIN LOOP.  GET KEYSTROKE FIRST
99 REM
100 GOSUB 990
105 PRINT BL$CW$(CM):IF CM=0 THEN 100
107 REM
108 REM DIRECTION COMMANDS
109 REM
110 IF CM<9 THEN GOSUB 300:GOTO 130
117 REM
118 REM ALL OTHER COMMANDS
119 REM
120 C=CM-8:ON C GOSUB 390,400,450,550,470,190,500,500
127 REM
128 REM CHECK FOR VICTORY
129 REM
130 IF PR=1 AND TL(9)=0 THEN FOR I=0 TO 999:NEXT:GOTO 940
140 PRINT BL$CW$(CM):GOTO 100
187 REM
188 REM "QUIT" ROUTINE
189 REM
190 PRINT "[147]PRESS Q TO QUIT":GOSUB 990:IF CM=14 THEN END
195 GOTO 350
297 REM
298 REM MOVEMENT HANDLER
299 REM
300 XX=XR:XR=PR:PR=RD(XR,CM)
302 REM
303 REM CHECK FOR SPECIAL CASES
304 REM
310 IF XR=7 AND TL(0)=0 AND PR=56 THEN GOSUB 900:PR=1:GOTO 350
315 IF PR=14 THEN GOSUB 905:GOTO 350
320 IF PR=56 AND XR=4 AND TL(2)=0 THEN GOSUB 920:PR=5:GOTO 350
325 IF PR=4 AND XR=5 AND TL(9)=0 THEN GOSUB 925:GOTO 350
342 REM
343 REM IS IT AN ILLEGAL MOVEMENT?
344 REM
345 DS$="":IF PR>49 THEN DS$=RN$(PR):PR=XR:XR=XX
346 REM
347 REM      * * *  RETURN POINT  * * *
348 REM TABLE SEARCH--ARE THERE ANY "THINGS" IN THE ROOM?
349 REM
350 TN$="":FOR I=0 TO 9:IF TL(I)=PR THEN TN$=TN$+TN$(I)+", "
355 NEXT:L=LEN(TN$):IF L>1 THEN TN$=LEFT$(TN$,L-2)
360 TT$=T$:IF TN$="" THEN TT$=""
362 REM
363 REM SET ROOM NAME TO PRESENT ROOM
364 REM
365 RN$=RN$(PR)
367 REM
368 REM IS IT THE FIRST VISIT TO THE ROOM?
369 REM
370 IF VS(PR)=0 THEN VS(PR)=1:GOTO 550
372 REM
373 REM CLEAR SCREEN AND PRINT ROOM NAME AND MESSAGE
374 REM
375 PRINT "[147]"CW$(CM)RL$RN$TT$TL$TN$DL$DS$
380 RETURN
387 REM
388 REM BACK COMMAND HANDLER
389 REM
390 XX=PR:PR=XR:XR=XX:RN$=RN$(PR):DS$="":GOTO 350
397 REM
398 REM "TAKE" ROUTINE
399 REM
400 I=0
405 IF TL(I)=PR THEN TL(I)=0:PP$=PP$+CHR$(I):DS$="GOT IT!":GOTO 350
410 IF LEN(PP$)>5 THEN GOSUB 450
415 I=I+1:IF I>9 THEN DS$="THERE'S NOTHING HERE.":GOTO 350
420 GOTO 405
447 REM
448 REM "LEAVE" ROUTINE
449 REM
450 IF LEN(PP$)<1 THEN DS$="YOU DON'T HAVE ANYTHING NOW.":GOTO 350
455 LT=ASC(LEFT$(PP$,1)):PP$=RIGHT$(PP$,LEN(PP$)-1)
460 TL(LT)=PR:DS$="":GOTO 350
467 REM
468 REM "GOT" HANDLER
469 REM
470 IF PP$="" THEN DS$="YOU'VE GOT NOTHING RIGHT NOW.":GOTO 350
475 DS$="YOU'VE GOT:"+C$+C$
480 FOR I=1 TO LEN(PP$):DS$=DS$+TS$(ASC(MID$(PP$,I,1)))+C$:NEXT
485 GOTO 350
497 REM
498 REM "HELP" ROUTINE
499 REM
500 PRINT "[147]"C$C$"THERE ARE 9 POSSIBLE DIRECTIONS:"
501 PRINT "N = NORTH"C$"S = SOUTH"C$"E = EAST"C$"W = WEST"C$"U = UP"
502 PRINT "D = DOWN"C$"I = IN"C$"O = OUT"C$"B = BACK TO PREVIOUS ROOM"C$
503 PRINT "OTHER COMMANDS ARE:"C$C$"T = TAKE THE FIRST OBJECT LISTED"
504 PRINT "L = LEAVE BEHIND WHATEVER YOU'VE BEEN       CARRYING LONGEST"
505 PRINT "P = PEER AT SURROUNDINGS"C$"G = LIST WHAT WE'VE GOT WITH US"
506 PRINT "Q = QUIT"C$"H = HELP"C$"? = HELP"C$
507 PRINT "(PRESS ANY KEY)";:GOSUB 990:PRINT "[147]":GOTO 350
547 REM
548 REM "PEER" JUMP TABLE
549 REM
550 PRINT "[147]"DL$
555 ON PR GOSUB 600,620,640,660,680,700,720,740,760,780,800,820,840,860
560 PRINT BL$CW$(CM)RL$RN$TT$TL$TN$
565 RETURN
597 REM
598 REM MAIN GATE DESCRIPTION
599 REM
600 PRINT "WE ARE STANDING ON THE BRIDGE LEADING"
601 PRINT "TO THE HUGE WOODEN GATE OF THE CASTLE."C$
602 PRINT "TO THE NORTH IS THE DEEP FOREST.  A"
603 PRINT "PATH LEADS AROUND THE CASTLE TO THE"
604 PRINT "EAST AND WEST.  THE WALLS ARE VERY HIGH"
605 PRINT "AND I CAN'T SEE ANYONE AT ALL."
615 RETURN
617 REM
618 REM WEST OF CASTLE
619 REM
620 PRINT "THE MEADOW IS FULL OF RABBITS, SO BE"
621 PRINT "CAREFUL WHERE YOU STEP.  THE FOREST IS"
622 PRINT "THICK TO THE WEST.  A PATH LEADS AROUND"
623 PRINT "THE CASTLE TO THE NORTH AND SOUTH."C$
624 PRINT "THE STONES OF THE CASTLE WALL ARE SLICK"
625 PRINT "AND COVERED WITH MOSS."C$
626 PRINT "LISTEN--YOU CAN HEAR A HORSE WHINNYING."
635 RETURN
637 REM
638 REM EAST OF CASTLE
639 REM
640 PRINT "PLEASE DON'T DANCE AROUND SO MUCH!"C$
641 PRINT "WE'RE ON A NARROW LEDGE ALONG THE EAST"
642 PRINT "EDGE OF THE CASTLE.  IT ENDS JUST A FEW"
643 PRINT "YARDS TO THE SOUTH."C$
644 PRINT "OVER THE EDGE IT'S A SHEER DROP FOR AT"
645 PRINT "LEAST TWO THOUSAND FEET.  THE EDGE IS"
646 PRINT "CRUMBLING A LITTLE, SO IF YOU DON'T"
647 PRINT "MIND, COULDN'T WE JUST GO BACK?"
655 RETURN
657 REM
658 REM SOUTH OF CASTLE
659 REM
660 PRINT "WE'RE IN A GROVE OF TREES ON A NARROW"
661 PRINT "WEDGE OF LAND JUST SOUTH OF THE CASTLE."C$
662 PRINT "THE LAND SLOPES DOWN TOWARD THE FOUNDA-"
663 PRINT "TION OF THE CASTLE TO THE NORTH, AND TO"
664 PRINT "THE SOUTH IT SLOPES UP TO A SUDDEN"
665 PRINT "DROP-OFF.  THERE'S A STEEP CLIFF TO THE EAST, TOO."C$
666 PRINT "THERE'S A COLUMN OF SMOKE RISING ABOVE  THE CASTLE WALL."
675 RETURN
677 REM
678 REM KITCHEN
679 REM
680 PRINT "THE KITCHEN FIRE IS BURNING HOTLY, BUT"
681 PRINT "THERE'S NO ONE IN THE ROOM."C$
682 PRINT "A LARGE OPEN DOORWAY LEADS OUT INTO THE"
683 PRINT "COURTYARD TO THE NORTH AND WEST.  THE"
684 PRINT "DOORWAY IS FILLED WITH FLIES.  NOT"
685 PRINT "FIREFLIES--THE LOWER-CLASS KIND."C$
686 PRINT "TO THE EAST THERE'S ANOTHER DOOR, AND"
687 PRINT "TO THE SOUTH THERE'S A GAP WHERE ONE"
688 PRINT "STONE HAS BEEN PULLED OUT OF THE"
689 PRINT "FOUNDATION.  IT'S THE SECRET POSTERN"
690 PRINT "DOOR, THE ONE WE CRAWLED THROUGH."C$
691 PRINT "THERE'S A LARGE TABLE IN THE MIDDLE OF"
692 PRINT "THE ROOM, WITH MORE FOOD ON IT THAN A"
693 PRINT "NORMAL PERSON COULD EAT IN A WEEK.";
695 RETURN
697 REM
698 REM COURTYARD
699 REM
700 PRINT "WE'RE IN AN OPEN AREA IN THE CENTER OF"
701 PRINT "THE CASTLE.  THE DOOR OF THE GREAT HALL IS JUST EAST OF US."C$
702 PRINT "THE KITCHEN IS TO THE SOUTH AND THERE   ARE STABLES TO THE WEST."C$
703 PRINT "TO THE NORTH IS THE GATEHOUSE, A THICK"
704 PRINT "BUILDING THAT SURROUNDS AND PROTECTS THEMAIN GATE."C$
705 PRINT "THE DIRT IN THE COURTYARD IS SMOOTH, AS"
706 PRINT "IF NO ONE HAD EVER WALKED HERE. THE ONLYFOOTPRINTS ARE YOURS."
715 RETURN
717 REM
718 REM GATEHOUSE
719 REM
720 PRINT "WE'RE HIGH UP IN THE GATEHOUSE, BY THE"
721 PRINT "WINDLASS THAT CONTROLS THE GATE.  IT'S"
722 PRINT "STUCK--ALL YOUR STRENGTH CAN'T BUDGE IT.SORRY I CAN'T HELP."C$
723 PRINT "THERE ARE SHORT STAIRWAYS LEADING UP TO"
724 PRINT "THE WALLS, AND ANOTHER STAIRWAY LEADING"
725 PRINT "DOWN TO THE COURTYARD BELOW US."C$
726 PRINT "HANGING FROM A SPIKE ON THE WALL IS A"
727 PRINT "SINGLE ELEPHANT'S TUSK.  IT'S TOO HIGH  TO REACH."
735 RETURN
737 REM
738 REM ON THE WALLS
739 REM
740 PRINT "WE'RE ON THE CASTLE WALLS, BEHIND THE"
741 PRINT "CRENELLATION.  WE CAN WALK ALL THE WAY"
742 PRINT "AROUND THE CASTLE.  THE ONLY PLACES WE"
743 PRINT "CAN GET OFF ARE THE GATEHOUSE AND THE"
744 PRINT "TOWER THAT RISES ABOVE THE GREAT HALL."C$
745 PRINT "PLEASE DON'T STAY UP HERE TOO LONG."
746 PRINT "THERE ARE BIRDS COMING CLOSER.  THEY"
747 PRINT "LOOK TO ME LIKE THE INSECT-EATING KIND,"
748 PRINT "AND A FIREFLY LIKE ME CAN'T HIDE VERY   EASILY."
755 RETURN
757 REM
758 REM GREAT HALL
759 REM
760 PRINT "WE'RE IN THE GREAT HALL OF THE CASTLE."
761 PRINT "A LARGE DOORWAY IN THE NORTH LEADS TO"
762 PRINT "THE COURTYARD, WHILE A SMALL DOOR TO  THE WEST GOES TO THE KITCHEN."
763 PRINT C$"THERE ARE TABLES AND BENCHES AROUND THE"
764 PRINT "ROOM, A HUGE FIRE PIT IN THE MIDDLE, ANDA THRONE AT ONE END."
765 PRINT C$"A LARGE TAPESTRY ON THE WALL PROCLAIMS"
766 PRINT "THAT THIS IS THE RESIDENCE OF THE COUNT OF OBSCURITY."C$
767 PRINT "A SMALL STAIRWAY GOES UP ALONG ONE WALL"
768 PRINT "AND BEHIND THE THRONE THERE'S A TRAP"
769 PRINT "DOOR THAT SOMEONE HAS CARELESSLY LEFT"
770 PRINT "HALF OPEN.";
775 RETURN
777 REM
778 REM COUNT'S CHAMBER
779 REM
780 PRINT "THE LARGE CURTAINED BED LOOKS RECENTLY"
781 PRINT "SLEPT IN, AND THE HEARTH COALS ARE STILLGLOWING."C$
782 PRINT "SMALL DOORS LEAD ONTO THE WALLS TO THE"
783 PRINT "NORTH AND WEST, WHILE SMALL CUPBOARD"
784 PRINT "DOORWAYS SEEM TO LURK BEHIND EVERY"C$"TAPESTRY."C$
785 PRINT "A STAIRWAY IN ONE CORNER GOES DOWN, AND"
786 PRINT "A NARROW LADDER LEADS UP THROUGH THE"
787 PRINT "CEILING.  I THINK I CAN HEAR FOOTSTEPS"
788 PRINT "ABOVE US.  PLEASE DON'T GO UP THERE."
795 RETURN
797 REM
798 REM TOWER LOOKOUT
799 REM
800 PRINT "WE'RE AT THE HIGHEST POINT OF THE"C$"CASTLE."C$
802 PRINT "IGNORE THE SOUND OF SOMEONE WALKING"
803 PRINT "AROUND.  IT ISN'T ANYBODY--JUST AN"
804 PRINT "EMPTY SUIT OF ARMOR THAT KEEPS WALKING"
805 PRINT "AROUND AND AROUND THE EDGE OF THE TOWER."
806 PRINT "AT LEAST I THINK IT'S EMPTY."C$
807 PRINT "WOULD YOU MIND TERRIBLY IF WE JUST WENT BACK DOWN THE LADDER?"
815 RETURN
817 REM
818 REM THE STABLES
819 REM
820 PRINT "THE FLOOR OF THE STABLE IS WOODEN, AND"
821 PRINT "SOME OF THE BOARDS ARE MISSING--TEST"
822 PRINT "EACH STEP BEFORE YOU PUT YOUR WEIGHT ON"
823 PRINT "IT.  IT LOOKS LIKE A LONG WAY DOWN IF"
824 PRINT "YOU FALL THROUGH.  OR IS THERE SOMETHINGUNDER THE STABLE?":PRINT
825 PRINT "THERE'S THAT WHINNYING SOUND.  IT SEEMS"
826 PRINT "TO BE COMING FROM THAT STALL, BUT THE"
827 PRINT "STALL IS EMPTY.":PRINT
828 PRINT "I DON'T MEAN TO SOUND TIMID, BUT THE"
829 PRINT "ONLY WAY OUT OF HERE IS THE EAST DOOR TOTHE COURTYARD."
835 RETURN
837 REM
838 REM THE DUNGEONS
839 REM
840 PRINT "WE'RE DOWN IN THE DUNGEONS, AND THE"
841 PRINT "ONLY LIGHT DOWN HERE IS ME.":PRINT
842 PRINT "AND I'M NOT ALL THAT BRIGHT.":PRINT
843 PRINT "LOTS OF LITTLE CELLS EVERYWHERE. MOSTLY"
844 PRINT "EMPTY.  NONE OF THEM WITH ANY LIVING"
845 PRINT "RESIDENTS.  UNLESS YOU COUNT RATS.":PRINT
846 PRINT "I DON'T SEE ANY DEATH TRAPS, BUT THEN, ICAN'T SEE MUCH OF ANYTHING."
855 RETURN
857 REM
858 REM THE TREASURE ROOM
859 REM
860 PRINT "WE MADE IT!  THERE ARE COINS AND INGOTS AND JEWELS EVERYWHERE!"
861 PRINT:PRINT "PAINTINGS, TOO.  AND SCULPTURES.":PRINT
862 PRINT "NO, DON'T TAKE ANY OF IT!  IT'S ALL"
863 PRINT "CURSED!  JUST THE ELEPHANT OF CIPANGU--"
864 PRINT "THAT'S ALL YOU CAN TAKE WITH YOU, IF"
865 PRINT "YOU WANT TO LIVE LONG AND PROSPER."
875 RETURN
900 RD(7,1)=1:RD(7,8)=1:RD(1,2)=7:RD(1,7)=7
901 DS$="USING THE GOLDEN KEY, YOU UNLOCK THE    TURNSTILE AND OPEN THE GATE"
902 RETURN
905 IF TL(4)=0 AND TL(5)=0 AND TL(8)=0 THEN 910
906 PR=XR:XR=XX:DS$=RN$(56):RETURN
910 PRINT "[147]"DL$"DON'T BE SO CLUMSY!  YOU SPILLED SOME"
911 PRINT "ALE FROM THE FLAGON ON THE PILLOW AND"
912 PRINT "THE MOUSE SUDDENLY WOKE UP AND DRANK IT"
913 PRINT "AND--WAIT A MINUTE--THE MOUSE IS"
914 PRINT "SPEAKING.  IT'S READING SOME ANCIENT"
915 PRINT "WORDS WRITTEN IN THE EMBROIDERY OF THE"
916 PRINT "PILLOW--AND THERE'S A SECRET DOOR,"
917 PRINT "BEGINNING TO GLOW BRIGHTLY--IT'S THE"
918 PRINT "TREASURE ROOM!  LET'S GO IN!"C$C$"(PRESS A KEY)"
919 GOSUB 990:DS$="":RETURN
920 PRINT "[147]"DL$"THERE'S A CRACK IN ONE FOUNDATION STONE"
921 PRINT "AND IF YOU JUST PRY A LITTLE WITH THE"
922 PRINT "BUTCHER KNIFE--YES, THAT'S IT.  GET YOURBACK INTO IT."C$
923 PRINT "YOU DID IT!  WE CAN CRAWL UNDER HERE ANDGET INSIDE.":PRINT
924 PRINT "(PRESS A KEY)":DS$="":GOSUB 990:RETURN
925 PR=5:XR=XX
926 DS$="YOU CAN'T GET THROUGH WITH THE ELEPHANT.I THOUGHT YOU KNEW THAT."
927 DS$=DS$+C$+"ONLY THE MAIN GATE WILL LET US PASS."
928 RETURN
937 REM
938 REM VICTORY HANDLER
939 REM
940 PRINT "[147]WE MADE IT!":PRINT:PRINT "WE'RE OUTSIDE THE CASTLE WITH THE"
941 PRINT "EMERALD ELEPHANT OF CIPANGU.  NOW YOU"
942 PRINT "CAN SEE AGAIN, AND I HAVE RECOVERED MY"
943 PRINT "TRUE FORM.  I KNOW I'M INCREDIBLY GOOD-"
944 PRINT "LOOKING, BUT DON'T BOTHER ASKING ME FOR"
945 PRINT "A DATE--YOU'RE FINE FOR EXPLORING"
946 PRINT "CASTLES, BUT I'M ENGAGED TO MARRY"
947 PRINT "SOMEBODY WITH ROYAL BLOOD AND A FORTUNE"
948 PRINT "BIGGER THAN THE NATIONAL DEBT.  YOU'VE"
949 PRINT "BEEN SWEET, THOUGH.  THANKS A BUNCH!":PRINT:PRINT "BYE!"
950 POKE 198,0:END
967 REM
968 REM RANDOMLY CHOOSE LOCATION OF TREASURE ROOM
969 REM
970 R=INT(10*RND(9)):IF R>2 THEN R=3
971 IF R=1 THEN R=0
972 ON R GOTO 975,980,985
975 X=2+INT(2*RND(9)):RD(10,X)=14:RETURN
980 RD(12,6)=14:RETURN
985 X=1+INT(8*RND(9)):R=13:IF RD(R,X)=55 THEN RD(R,X)=14:RETURN
986 GOTO 985
990 A=PEEK(197):IF A=64 THEN 990
995 CM=KS(A):RETURN
997 REM
998 REM SET UP COMMAND WORD ARRAY
999 REM
1000 FOR I=0 TO 16:READ A$:CW$(I)=A$:NEXT
1010 DATA "WHAT?","NORTH","SOUTH","EAST","WEST","UP","DOWN","IN","OUT","BACK"
1015 DATA "TAKE","LEAVE","PEER","GOT?","QUIT","HELP","HELP"
1047 REM
1048 REM SET UP KEYSTROKE ARRAY
1049 REM
1050 FOR I=0 TO 64:KS(I)=0:NEXT
1055 FOR I=1 TO 16:READ A:KS(A)=I:NEXT
1060 DATA 39,13,14,9,30,18,33,38,28,22,42,41,26,62,29,55
1097 REM
1098 REM SET UP RD (ROOM DIRECTION TABLE) AND RN$ (ROOM NAME TABLE)
1099 REM
1100 FOR I=1 TO 14:READ A$:RN$(I)=A$:FOR J=1 TO 8:READ A:RD(I,J)=A:NEXT:NEXT
1110 DATA "CASTLE MAIN GATE",52,53,3,2,51,50,53,50
1115 DATA "MEADOW WEST OF CASTLE",1,4,51,52,51,50,51,50
1120 DATA "LEDGE EAST OF CASTLE",1,54,54,51,51,51,51,50
1125 DATA "GROVE SOUTH OF CASTLE",51,54,54,2,51,56,53,50
1130 DATA "KITCHEN",6,4,9,6,50,13,9,6
1135 DATA "COURTYARD",7,5,9,12,7,5,9,7
1140 DATA "GATEHOUSE",56,6,8,8,8,6,6,56
1145 DATA "ON THE WALLS",7,10,10,7,57,51,7,50
1150 DATA "GREAT HALL",6,50,50,5,10,13,5,6
1155 DATA "COUNT'S CHAMBER",8,55,55,8,11,9,50,8
1160 DATA "TOWER TOP",54,54,54,54,57,10,50,50
1165 DATA "THE STABLES",50,50,6,50,50,55,50,6
1170 DATA "THE DUNGEONS",55,55,55,55,9,55,50,50
1175 DATA "TREASURE ROOM",50,50,50,50,50,50,50,50
1197 REM
1198 REM SET UP RN$ VALUES FOR ILLEGAL MOVEMENT DIRECTIONS
1199 REM
1200 FOR I=50 TO 57:READ A$:RN$(I)=A$:NEXT
1210 DATA "SORRY, BUT WE CAN'T GO THAT WAY"
1215 DATA "IT'S TOO STEEP FOR US TO CLIMB"
1220 DATA "WE'LL JUST GET LOST IF WE WANDER IN THE WOODS"
1225 DATA "I'M KNOCKING, BUT NOBODY ANSWERS"
1230 DATA "ARE YOU TRYING TO GET US KILLED?"
1235 DATA "I SEARCHED THERE, FOUND NOTHING, AND    CAME BACK"
1240 DATA "WE DON'T HAVE WHAT IT TAKES TO GET IN   THERE"
1245 DATA "UP FROM HERE?  DO YOU THINK YOU CAN FLY?"
1297 REM
1298 REM SET UP THE "THING" TABLE BY NAMING OBJECTS AND PUTTING THEM IN ROOMS
1299 REM
1300 FOR I=0 TO 9:READ A$,B$:TN$(I)=A$:TS$(I)=B$:NEXT
1310 DATA "A GOLDEN KEY","KEY","A LOAF OF RYE BREAD","BREAD"
1315 DATA "A BUTCHER KNIFE","KNIFE","A POCKET SUNDIAL","SUNDIAL"
1320 DATA "A DELICATELY EMBROIDERED PILLOW","PILLOW"
1325 DATA "A LIMP, MOTIONLESS MOUSE","MOUSE"
1330 DATA "A PARCHMENT CODEX","CODEX","AN ORANGE RIND","RIND"
1335 DATA "A FLAGON OF ALE","FLAGON"
1340 DATA "THE EMERALD ELEPHANT OF CIPANGU","ELEPHANT"
1347 REM
1348 REM PUT EACH THING IN ITS ROOM
1349 REM
1350 FOR I=0 TO 9:READ A:TL(I)=A:NEXT
1355 DATA 3,5,4,6,10,13,9,11,7,14
1990 RETURN